论文复现：低碳转型冲击就业吗？

发布时间：2023-04-08 阅读 913

Stata连享会主页 || 视频 || 推文 || 知乎 || Bilibili 站

温馨提示： 定期清理浏览器缓存，可以获得最佳浏览体验。

New！ lianxh 命令发布了：
随时搜索推文、Stata 资源。安装：
. ssc install lianxh
详情参见帮助文件 (有惊喜)：
. help lianxh
连享会新命令：cnssc, ihelp, rdbalance, gitee, installpkg

✌ 课程详情： https://gitee.com/lianxh/Course

⛳ 课程主页： https://gitee.com/lianxh/Course

⛳ Stata 系列推文：

全部 | Stata入门 | Stata教程 | Stata资源 | Stata命令
计量专题 | 论文写作 | 数据分享 | 专题课程
结果输出 | Stata绘图 | 数据处理 | Stata程序
回归分析 | 面板数据 | 交乘项-调节 | IV-GMM
内生性-因果推断 | 倍分法DID | 断点回归RDD | PSM-Matching | 合成控制法
Probit-Logit | 时间序列 | 空间计量 | 分位数回归 | 生存分析 | SFA-DEA
文本分析-爬虫 | Python-R-Matlab | 机器学习
Markdown | 工具软件 | 其它

☝ PDF下载 - 推文合集

作者：刘淑云 (中国农业大学)
邮箱：s.liu@cau.edu.cn

编者按：本文主要整理自下文，特此致谢！
Source：王锋，葛星. 低碳转型冲击就业吗——来自低碳城市试点的经验证据[J]. 中国工业经济，2022(5):81-99. -PDF- -Data-

1. 引言

中国已经持续推进多年的绿色低碳转型在实现节能减排目标的同时是否冲击了就业？现有文献表明，经济低碳转型导致高耗能高排放的污染型行业大量裁员，冲击了就业 (Ferris 等，2014)。但也有文献表明，经济社会的低碳转型趋势会引导或倒逼企业进行清洁生产，进而创造出绿色就业机会 (Fankhauser 和 Jotzo，2018)。因此，现有研究并没有充分回答中国的低碳转型是否冲击了就业。

为了有效控制温室气体排放，积极探索低碳发展经验，国家发展改革委于 2010 年、2012 年和 2017 年先后开展了三批低碳省区和低碳城市试点工作。该试点政策的推行为评估低碳转型对经济、环境和社会的影响提供了独特的“准自然试验”，因而为评估低碳转型对就业的影响效应提供了契机。

文章要回答的问题如下：

低碳转型是否会冲击就业？
影响机制是什么？
低碳转型对企业就业的影响，在不同所有制企业、不同年龄的企业、不同产业和不同行业中是否存在差异？

2. 理论机制

低碳城市试点政策通过产出效应和要素替代效应这两个机制影响就业。

产出效应是指低碳城市试点政策通过影响企业产出进而影响就业，具体可通过遵循成本说和创新补偿说两个方面影响产出进而影响就业，产出效应一般直接导致就业人数的绝对变化。

要素替代效应是指低碳城市试点政策通过影响企业环境治理投资进而影响就业。一方面，低碳城市试点政策必然会加强对企业污染物排放的约束，进而会增加其为遵守环境政策而产生的环境治理投资等“准固定”要素；另一方面，“准固定”要素对就业影响取决于“准固定”要素与劳动是替代还是互补关系。要素替代效应表现为不同就业岗位的替代。

3. 研究设计

3.1 模型构建

考虑到低碳城市试点政策是分三批启动，本文使用渐进双重差分模型进行评估。

模型1：低碳城市试点政策的减排效果评估模型：

c o 2_{c t} = α_{1} + θ_{1} c i t y l c c p o s t_{c t} + λ_{1} Z_{c t}^{1} + η_{c} + μ_{t} + ϵ_{c t}^{1}

其中，被解释变量 $c o 2_{c t}$ 是指城市 $c$ 在 $t$ 年的碳排放量；核心解释变量 $c i t y l c c p o s t_{c t}$ 是城市 $c$ 在 $t$ 年是否实施了低碳城市试点的虚拟变量； $Z_{c t}^{1}$ 代表 $t$ 年影响城市 $c$ 碳排放量的一系列控制变量，包括经济发展水平 (pgdp)、人口规模 (pop)、工业化水平 (ind)、城镇化水平 (urb) 和能源结构 (es)； $η_{c}$ 和 $μ_{t}$ 分别表示城市固定效应和年份固定效应； $ϵ_{c t}^{1}$ 是影响城市碳排放量的随机扰动项。 $θ_{1}$ 为双重差分估计量，衡量了低碳城市试点对城市碳排放量的影响效果。

模型2：低碳城市试点政策对城市层面就业影响的评估模型：

c i t y l a b o r_{c t} = α_{2} + θ_{2} c i t y l c c p o s t_{c t} + λ_{2} Z_{c t}^{2} + η_{c} + μ_{t} + ϵ_{c t}^{2}

其中，被解释变量 $c i t y l a b o r_{c t}$ 代表城市 $c$ 在 $t$ 年的就业，用城市在岗职工平均人数的对数表示； $Z_{c t}^{2}$ 代表 $t$ 年影响城市 $c$ 就业的一系列控制变量，包括人口规模 (pop)、城市工资水平 (citywage)、经济发展水平 (pgdp) 和消费水平 (rsc)； $ϵ_{c t}^{2}$ 是影响城市就业的随机扰动项。 $θ_{2}$ 为双重差分估计量，衡量了低碳城市试点对城市就业的影响效果。

模型3：低碳城市试点政策对企业层面就业影响的评估模型：

l a b o r_{i t} = α_{3} + θ_{3} l c c p o s t_{i t} + λ_{3} X_{i t} + ϕ_{i} + μ_{t} + ϵ_{i t}

其中，被解释变量 $l a b o r_{i t}$ 代表企业 $i$ 在 $t$ 年的员工就业人数，用企业员工总数的对数表示；核心解释变量 $l c c p o s t_{i t}$ 表示 $t$ 年企业 $i$ 所在城市是否实施了低碳城市试点政策； $X_{i t}$ 代表 $t$ 年影响企业 $i$ 员工就业的一系列控制变量，包括企业工资水平 (wage)、企业规模 (size)、资产负债率 (lev)、销售费用率 (ser)、所得税费用 (tax)、成长能力 (grow) 和总资产净利润率 (roa)； $ϕ_{i}$ 表示企业固定效应； $ϵ_{i t}$ 是影响企业层面就业的随机扰动项。 $θ_{3}$ 为双重差分估计量，从企业层面衡量了低碳城市试点对就业的影响。

3.2 样本选择和数据来源

宏观数据以 2007-2019 年中国 287 个城市为研究样本。其中，有 121 个城市为试点城市，166 个城市为非试点城市，三批低碳城市试点政策的起始时间分别为 2010、2013 和 2017。

城市碳排放量用城市二氧化碳排放量的对数表示，数据来源于 China Emission Accounts&Datasets (CEADs)。城市就业水平用城市在岗职工平均人数的对数表示，该数据和城市层面控制变量的数据均来源于《中国城市统计年鉴》(2008一2020)。

微观数据选择 2007-2019 年中国沪深两市 A 股上市公司为研究样本，数据来源于国泰安数据库。

4. Stata实现

4.1 基准回归结果

表 1：低碳城市试点政策对城市碳排放量和就业的影响

. lxhuse cabemp_city.dta, clear
. xtset 城市编号 年度
. global firmvar1 pgdp pop ind urb es
. global firmvar2 citywage pop pgdp rsc

. * 模型 (1) 
. reghdfe co2 citylccpost $firmvar1, absorb(城市 年度) vce(cluster 城市)
. est store m1
. * 模型 (2) 
. reghdfe citylabor citylccpost $firmvar2, absorb(城市 年度) vce(cluster 城市) 
. est store m2
. esttab m1 m2, star(* 0.1 ** 0.05 *** 0.01) nogap

--------------------------------------------
                      (1)             (2)   
                      co2       citylabor   
--------------------------------------------
citylccpost       -0.0295*         0.0756***
                  (-1.93)          (3.40)   
pgdp               0.0837***        0.190***
                   (3.53)          (3.18)   
pop                0.0909           0.884***
                   (1.12)          (4.74)   
ind              0.000821                   
                   (1.38)                   
urb                0.0212***                
                   (6.61)                   
es                  0.534***                
                   (3.91)                   
citywage                          -0.0332   
                                  (-1.55)   
rsc                                0.0378** 
                                   (2.43)   
_cons               9.464***       -4.169***
                  (15.99)         (-3.57)   
--------------------------------------------
N                    3705            3705   
--------------------------------------------
t statistics in parentheses
* p<0.1, ** p<0.05, *** p<0.01

表 2：低碳城市试点政策对企业就业的影响

. lxhuse cabemp_firm.dta, clear
. xtset id year
. global deptvar labor
. global firmvar wage size lev ser tax grow roa
. reghdfe labor lccpost, absorb(id year) vce(cluster id)
. est store m1
. reghdfe labor lccpost $firmvar, absorb(id year) vce(cluster id)
. est store m2
. esttab m1 m2, star(* 0.1 ** 0.05 *** 0.01) nogap

--------------------------------------------
                      (1)             (2)   
                    labor           labor   
--------------------------------------------
lccpost            0.0602***       0.0511***
                   (2.72)          (3.00)   
wage                             -0.00552***
                                  (-3.01)   
size                                0.606***
                                  (24.17)   
lev                                 0.220***
                                   (3.12)   
ser                                 0.495***
                                   (2.78)   
tax                                0.0126***
                                   (2.58)   
grow                               0.0228***
                                   (4.56)   
roa                               -0.0841   
                                  (-0.91)   
_cons               7.702***       -0.485   
                 (678.60)         (-1.55)   
--------------------------------------------
N                   22903           22903   
--------------------------------------------
t statistics in parentheses
* p<0.1, ** p<0.05, *** p<0.01

4.2 平行趋势假定检验

. lxhuse cabemp_firm.dta, clear
. cap drop G-eventt11
. * G 是按照政策实施时间对样本进行分类
. gen G=0 if policy==2050
. replace G=1 if policy==2010
. replace G=2 if policy==2013
. replace G=3 if policy==2017

. * event 表示政策实施前后几年，政策实施前4年汇总到第-4期，政策实施后六年汇总到第6期
. gen event = year - policy if G>0
. tab event
. replace event = -4 if event <= -4
. replace event = 6  if event >= 6
. replace event =.   if G==0
. tab event, gen(eventt)
. forvalues i = 1/11{
  2.     replace eventt`i' = 0 if eventt`i' == .
  3. }
. drop eventt1
. reghdfe labor eventt* $firmvar, absorb(id year) vce(cluster id)
. coefplot, baselevels keep(eventt*) vertical yline(0) ytitle("政策动态效应")   ///
>     xtitle("低碳城市试点政策实施的相对时间") addplot(line @b @at)               ///
>     ciopts(recast(rcap)) scheme(s1mono) levels(95) coeflabels(eventt2 = "-3" ///
>     eventt3 = "-2" eventt4 = "-1" eventt5 = "0" eventt6 = "1" eventt7  = "2" ///
>     eventt8  = "3" eventt9  = "4" eventt10  = "5" eventt11  = ">=6")
. graph export "平行趋势检验.png", as(png) replace width(800) height(600)

4.3 时间安慰剂检验

. lxhuse cabemp_firm.dta, clear
. * lccpostfalse1 lccpostfalse2 lccpostfalse3 lccpostfalse4 
. * 分别表示实施政策提前2年、3年、4年和5年
. reghdfe labor lccpostfalse1 $firmvar, absorb(id year) vce(cluster id)
. est store m1
. reghdfe labor lccpostfalse2 $firmvar, absorb(id year) vce(cluster id)
. est store m2
. reghdfe labor lccpostfalse3 $firmvar, absorb(id year) vce(cluster id)
. est store m3
. reghdfe labor lccpostfalse4 $firmvar, absorb(id year) vce(cluster id)
. est store m4
. esttab m1 m2 m3 m4, star(* 0.1 ** 0.05 *** 0.01) nogap  ///
>     order(lccpostfalse1 lccpostfalse2 lccpostfalse3 lccpostfalse4)

----------------------------------------------------------------------------
                      (1)             (2)             (3)             (4)   
                    labor           labor           labor           labor   
----------------------------------------------------------------------------
lccpostfal~1       0.0106                                                   
                   (0.51)                                                   
lccpostfal~2                      -0.0104                                   
                                  (-0.41)                                   
lccpostfal~3                                      -0.0304                   
                                                  (-1.14)                   
lccpostfal~4                                                      -0.0226   
                                                                  (-0.75)   
wage             -0.00553***     -0.00553***     -0.00554***     -0.00553***
                  (-3.01)         (-3.01)         (-3.02)         (-3.01)   
size                0.606***        0.606***        0.606***        0.606***
                  (24.19)         (24.17)         (24.17)         (24.19)   
lev                 0.222***        0.222***        0.222***        0.222***
                   (3.15)          (3.16)          (3.15)          (3.15)   
ser                 0.497***        0.498***        0.498***        0.497***
                   (2.80)          (2.81)          (2.81)          (2.80)   
tax                0.0125**        0.0125**        0.0125**        0.0125** 
                   (2.56)          (2.56)          (2.56)          (2.57)   
grow               0.0229***       0.0228***       0.0227***       0.0227***
                   (4.57)          (4.55)          (4.52)          (4.54)   
roa               -0.0842         -0.0832         -0.0825         -0.0840   
                  (-0.91)         (-0.90)         (-0.89)         (-0.90)   
_cons              -0.464          -0.446          -0.429          -0.438   
                  (-1.48)         (-1.42)         (-1.37)         (-1.40)   
----------------------------------------------------------------------------
N                   22903           22903           22903           22903   
----------------------------------------------------------------------------
t statistics in parentheses
* p<0.1, ** p<0.05, *** p<0.01

5. 相关推文

Note：产生如下推文列表的 Stata 命令为：
lianxh 论文复现, m
安装最新版 lianxh 命令：
ssc install lianxh, replace

专题	嘉宾	直播/回看视频
⭐ 最新专题		文本分析、机器学习、效率专题、生存分析等
研究设计	连玉君	我的特斯拉-实证研究设计，-幻灯片-
面板模型	连玉君	动态面板模型，-幻灯片-
面板模型	连玉君	直击面板数据模型 [免费公开课，2小时]

论文复现：低碳转型冲击就业吗？

1. 引言

2. 理论机制

3. 研究设计

3.1 模型构建

3.2 样本选择和数据来源

4. Stata实现

4.1 基准回归结果

4.2 平行趋势假定检验

4.3 时间安慰剂检验

5. 相关推文

相关课程

免费公开课

最新课程-直播课

⛳ 课程主页

⛳ 课程主页

关于我们

热门资讯