Stata：提高对转换和非线性效应认识的8个建议

发布时间：2022-01-30 阅读 1910

Stata连享会主页 || 视频 || 推文 || 知乎 || Bilibili 站

温馨提示： 定期清理浏览器缓存，可以获得最佳浏览体验。

New！ lianxh 命令发布了：
随时搜索推文、Stata 资源。安装：
. ssc install lianxh
详情参见帮助文件 (有惊喜)：
. help lianxh
连享会新命令：cnssc, ihelp, rdbalance, gitee, installpkg

✌ 课程详情： https://gitee.com/lianxh/Course

⛳ 课程主页： https://gitee.com/lianxh/Course

⛳ Stata 系列推文：

全部 | Stata入门 | Stata教程 | Stata资源 | Stata命令
计量专题 | 论文写作 | 数据分享 | 专题课程
结果输出 | Stata绘图 | 数据处理 | Stata程序
回归分析 | 面板数据 | 交乘项-调节 | IV-GMM
内生性-因果推断 | 倍分法DID | 断点回归RDD | PSM-Matching | 合成控制法
Probit-Logit | 时间序列 | 空间计量 | 分位数回归 | 生存分析 | SFA-DEA
文本分析-爬虫 | Python-R-Matlab | 机器学习
Markdown | 工具软件 | 其它

☝ PDF下载 - 推文合集

作者：费钰婷 (中山大学)
邮箱：feiyt@mail2.sysu.edu.cn

编者按：本文主要摘译自下文，特此致谢！
Source：Rönkkö M, Aalto E, Tenhunen H, et al. Eight simple guidelines for improved understanding of transformations and nonlinear effects[J]. Organizational Research Methods, 2022, 25(1): 48-87. -PDF-

在分析前转换变量或将转换作为一般化线性模型的一部分是组织研究中常有的动作。近期有好几篇直接或间接涉及这个话题的方法论文章发表。在这篇文章里，我们指出一些关于转换的误解并提出 8 个简单指导。

我们的主要观点是转换的选择不应该基于单个变量的本性或分布，而应该基于从理论或实证研究中得到的 2 个及以上变量之间关系的函数形式。在对 6 个顶级管理期刊建立系统性回顾后，我们指出几个能提高非线性模型的规范和解释性的方法。

1. 背景介绍

非线性模型在组织研究中十分常见。例如，非线性模型被用于收益递减模型(Cennamo，2018)，U 型效应 (Huang 等，2018)，S 型效应 (Brands 和 Fernandez-Mateo，2017 )，或者相对效应 (York 等，2018)。一个非线性模型可从以下方式构建：

在分析前对变量进行非线性转换；
或在估计模型中加入非线性转换。

第一种方法的典型解释是：一个统计工具，如 OLS 回归，需要正态分布的数据，而转换可以使分布更接近于正态 (例如，通过减少 skewness)。第二种方法的典型解释是：一个离散的 (例如，二元、计数) 因变量要求特殊的模型工具，如 GLMs、Logistic 回归、概率回归、泊松回归和负二项回归都是这个方法的特殊例子。

在这篇文章里，我们解释了为什么任何依赖于变量分布的理由都是错误的。我们文章有 2 个主要贡献：

第一，我们展示了转换无论作为模型的一部分还是作为在估计前的人为应用，都必须考虑 2 个变量间的关系，而不是基于单个变量的分布；
第二，我们讨论了非线性模型的解释，这是一个在近期指导中要么被忽视要么被错误理解的事情 (Becker 等 2019；Blevins 等，2015)。

这篇文章的结构是一系列建议，由对书籍和文章的回顾得出，包括计量经济学 (例如，Angrist 和 Pischke，2009；Greene，2003；Wooldridge，2002/2013)，社会学 (例如，Breen 等 2018；Long 和 Mustillo，2019；Mize，2019)，以及数据可视化 (例如，Breheny 和 Burchett，2017；Cattaneo 等，2019；Mitchell，2012a)，以及对六大顶尖管理期刊近期文章的回顾。

建议	解释
建议 1：基于函数形式而不是变量分布来确定转换。	1. 转换改变了变量间的函数形式，估计了改变怎样的效果。2. 变量的非正态性不是需要解决的问题，但一个非正态的因变量可能显示了需要被考虑的一个非线性过程。
建议 2：假设应该尽可能地展现联系的形式。	1. 一个统计模型要求明确一个函数形式，这应该基于理论完成。2. 函数形式可使用思想实验假设或实证诊断发现。
建议 3：不要转换因变量；使用GLM。	1. GLM 模型的理解方式与拥有转换因变量的线性模型相同。2. GLM 在方法论上和实践中都比转换因变量更好。
建议 4：首先选择 GLM 作为联系函数。如果这样做了，然后转换自变量。	1. GLM 联系函数决定了单个变量是如何影响因变量，以及变量是如何共同作用的。2. 在线性模型中，自变量是可加地组合。在指数模型中，自变量是相乘地组合。
建议 5：基于一致性而不是模型适用选择 GLM 分布。	1. GLM 联系函数应该基于曲线的一致性而不是分布的适合性选择。2. 对线性使用 OLS，对指数使用泊松 QML，对二元和部分响应模型使用 Logit QML。
建议 6：当建模 U 型和其他曲线效应时，不要在幂变换中 default，而要考虑不同的替代。	1. 幂变换 (比如， $x^{2} * x * 2$ ) 假定了 U 型效应的一个特定形式，而这可能对数据来说是不对的。2. 考虑指数模型和回归样条作为估计非线性模型的替代。
建议 7：通过绘图来理解非线性效应，包括置信区间和数据。	1. 通过标出调整后预估来理解非线性模型，并在绘制中清楚地展示非线性的本质。2. 包括置信带来展现估计量的不确定性，并绘制数据或 contour 图来展现选择的函数形式能较好地符合。
建议 8：不要从交互作用而是从图中推出适度。	1. 除非假设说明了效应的形式 (例如，相对，绝对 ) ，不然适度假设 (moderation hypothesis ) 是模糊的。2. 即使交互项不显著，也使用绘图来理解非线性模型的 moderation hypothesis。

2. 在组织研究中使用转换

下图展示了常用的转换：

2.1 建议 1：基于函数形式而不是变量分布来确定转换

在使用转换中，因变量的非正态性是一个常见理由。一个非正态的因变量会给 OLS 回归带来问题的说法是不对的，进而也无法提供足够的理由来进行转换。事实上，回归是无偏和一致的证据不需要任何有关于自变量、因变量和误差项分布的假设。其需要的是以下条件：

随机样本；
总体上自变量和因变量的关系是线性的；
每个因变量都对模型增添了方差不齐性 (unique variance)；
无内生性问题。

如果这四条成立，非正态的误差项和离散的因变量也不会给回归带来问题。

某些 OLS 回归属性的证明需要有关分布的假设，但这些假设仅跟误差项有关 (条件分布) 而跟自变量和因变量无关 (非条件分布)。第一个假设是同方差性。转换被认为是解决异方差问题的办法。然而，这是无效的且会将原本的线性模型变为非线性。

Heteroskedasticity-consistent (robust) standard errors (异方差一致性 robust 标准误) 是一个更好的解决办法。其在异方差性未知的情况下也是有效的，能保留原有模型，且能通过常用的统计软件实现。第二个假设是误差项服从正态分布。但这个假设经常跟实际研究无关，因为 OLS 回归的大样本行为从样本数小于 100 时便开始了，而大样本行为并不取决于误差项的正态分布。

2.2 实例说明

我们使用来自 Fox (1997) 的 Prestige 数据集，这个数据集包含了 1971 年加拿大人口普查提供的 102 种职业的数据。为了简便，我们只关注 3 个变量：Income 是每种职业的平均年薪，education 是平均受教育年限，women是每种职业中的女性占比。之后，我们还将使用 prestige 表示每种职业的声望。

我们使用回归以理解教育对收入的影响，控制职业中的女性占比。

* Load the dataset from UCLA website.
. use https://stats.idre.ucla.edu/stat/stata/examples/ara/prestige, clear

* Descriptive statistics and correlations of the prestige data
. sum income educat percwomn prestige 
. correlate income educat percwomn prestige 

* All regression models discussed in the paper. We use heteroskedasticity 
* consistent (robust) standard errors for all models. Cataloging and tabulating
* the models is done with the estout package. To install, type
* ssc install estout
. generate lnincome = ln(income)
. eststo m1: regress income educat percwomn, vce(robust)
. eststo m2: regress lnincome educat percwomn, vce(robust)
. eststo m3: poisson income educat percwomn, vce(robust)
. eststo m4: poisson income educat percwomn prestige, vce(robust)
. eststo m5: regress income c.educat##c.percwomn, vce(robust)
. eststo m6: poisson income c.educat##c.percwomn, vce(robust)

* The regression table 
. esttab m1 m2 m3 m4 m5 m6

* Average marginal/partial effects for all non-linear or interaction models
* using the margins package

. estimates restore m3
. margins, dydx(educat percwomn)
. estimates restore m4
. margins, dydx(educat percwomn prestige)
. estimates restore m5
. margins, dydx(educat percwomn)
. estimates restore m6
. margins, dydx(educat percwomn)

得到的结果如下表所示。Model 1 说明每增加一年受教育时间，年薪大约增加 $950，而 Model 2 (因变量进行 log 转换) 表明多受 1 年教育会使年薪在现有基础上提高 13%。

画图以比较 normal linear model 和 model using log transformed dependent variable 的边际预测。

* Figure 1: Comparison of marginal predictions from normal linear model and one
* using log transformed dependent variable. We use the user-written 
* combomarginsplot command to combine the two sets of adjusted predictions. To 
* install, type
* ssc install combomarginsplot
. estimates restore m1
. margins, at(educat=(6(.2)16)) saving(mar1, replace) 
. estimates restore m2
. margins, at(educat=(6(.2)16))  expression(exp(predict())) saving(mar2, replace) 
. combomarginsplot mar1 mar2, noci plotopts(msymbol(none)) ///
>     addplot(scatter income educat, below mcolor(black)   ///
>     msymbol(circle_hollow) legend(order(1 "Linear" 2 "Exponential"))) ///
>     legend(ring(0) position(11) rows(2)) name(Figure1, replace)

结果如下图所示。指数增长并不是很陡峭，接近于一条直线。虽然线性模型足以较好地实现预测的目的，但理解潜在的曲线型对于研究来讲仍然十分重要，因为非线性模型会给理论检验和实践建议带来不同的含义。

研究方面，线性和指数增长要求不同的随机过程。由于钱的边际效用递减，收入的增长应该与当前收入水平成正比。如果教育对收入的效应并不是与当前收入水平成正比，人们就不会接受更多教育因为教育的边际效用在递减。

实践方面，假定教育的不同年限对收入有相同的影响 (例如，线性影响)，那么 3 年的硕士学历就不值得它所花费的时间和金钱，12 年的义务教育足以产生 15 年教育中 80% 的效果。

在这个例子中，指数曲线在理论上和实证上都更吸引人，并导致了更现实的实践建议。然而，线性和有着 log 形式因变量的指数模型都没有很好地反映数据，都低估了最高收入。后文中我们将提出解决这个问题的建议。但目前我们已经发现对因变量进行 log 转换将对关系的理解从线性转为指数。

总结：(a) OLS 回归假定变量间的所有关系总体上是线性的。因为转换允许在线性模型框架内刻画非线性关系，所以转换是有用的。(b) OLS 回归并没有假定观察变量正态分布，正态性假设只存在于误差项并且这个假设不重要。(c) 估计标准误时异方差性会是个问题，但使用转换来解决这个问题是无效的并且会导致非线性模型，而不是原本计划的模型。使用 robust 标准误是个更好的替代办法。

因此，转换变量不能是因为要减轻回归的分布假设受损导致的影响。如果误差项不是正态分布和同方差的话，使用线性回归是种常见并可接受的办法。然而，数据的非正态分布，特别是偏度 (skewness)，表明了一种非线性效应，这个效应不能被忽略且需要研究其来源。

3. 对使用转换建模的建议

我们现在将集中在对实际研究的建议，从如何明确使用转换的模型开始。我们中心观点是转换，无论是通过人工还是 GLM 进行的，理论上和实证上都应该基于变量间预期的函数形式，而不是基于变量的分布。

3.1 建议 2：假设应该尽可能地展现联系的形式

变量之间的估计关系可以通过其形式、强度和统计意义来表征。然而，组织理论几乎普遍忽略关系的形式或强度，只关注其存在和方向，这种不精确性扩展到了用于测试数据的假设理论。

在假设中不指定函数形式是有问题的，因为当假设被检验时需要一个函数形式。在 Prestige 数据集中考虑以下假设：

假设 1：教育的增加与收入的增加有关。

为了测试这条语句，必须将其形式化为一个等式。这里假设的不精确性显而易见：这仅仅意味着教育的增加总会产生积极的影响，但并不清楚其形式 (线性、指数等) 或强度 (教育对收入的影响有多大)。换句话说，这意味着 “提议的关系只是一些单调函数”。

然而，需要指定函数形式来构建用于测试函数的统计模型。目前解决这一问题的做法是假设直线是最合适的函数形式。这些假设应该明确。函数形式应要么以理论为基础，并在假设中指定，或从数据中导出。

基于理论确定函数形式的策略。理想的战略是使函数形式作为假设的一部分进行陈述。如果使用 (近似) 线性效果预期，该假设可以表述为：

假设 1a：预期收入随教育程度线性增加。

然而，正如我们前面介绍示例时所解释的，在这种情况下，指数函数形式更有意义，因为货币的边际效用在下降。因此假设 1 可以通过三种替代形式之一进行细化和呈现：

假设 1b：教育的增加与收入的增加有关，这种效应是相对于当前收入水平 (即，增加当前价值的百分比)。

同样的假设也可以用更简洁的形式表述：

假设 1c：相对于当前收入，教育增加了收入。

或者我们可以明确提到相对效应产生的指数增长：

假设 1d：收入随教育呈指数增长。

尽管示例中函数形式的选择很简单，但并不总是如此。在某些情况下，因变量的性质可能暗示特殊形式。除了收入和工资，还有其他几个常用的变量，几乎总是以百分比变化来考虑，如公司增长、收入或投资。当因变量以某个区间为界时，可以安全地假设关系遵循 S 形曲线，以便随着假设预测因子的增加，因变量越来越接近区间的终点，但一旦接近，接近端点的速度将减小。

例如，如果我们认为一个初创公司的收购概率在 30% 开始，获得一个新的重要专利可能会增加到 40%。然而，如果初始概率已经达到 90%，那么公司实施的任何变更都只能产生增量效应，公司所做的任何事情都不能确保收购 (即 100%)。

在其他情况下，函数形式的选择可能不太明确。继 Jaccard 和 Jacoby (2020，第6章) 之后，我们建议使用思维实验。在 Jaccard 和 Jacoby 提出的第一种策略中，研究人员首先在一张空白纸上绘制 x 轴和 y 轴，然后在绘图区域的某个地方绘制起点。在这之后，下一个点将通过将 x 增加一个单位并考虑 y 的典型变化量来绘制。

然后，考虑到增加一个单元会产生什么样的影响，下一点也会类似地画出来。增长率是恒定 (线性)、加速还是递减？效果总是朝着同一个方向吗？也许存在一个阈值，在该阈值之后效果会发生变化？考虑到之前的研究可能会有所帮助。例如，收益递减和成本上升可运用对数和指数形式 (Haans 等人，2016)。我们强调这是一个概念性练习，研究人员可以自由思考和提出函数形式，而不受如何将这些形式表达为特定功能的任何限制。

Jaccard 和 Jacoby 提出的第二个策略 (2020，第6章) 是画出两种或更多种可供选择的形式，然后考虑该现象遵循这种形式需要什么。当因变量是一个相对客观的数量，如收入、增长率或盈利能力时，在使用此策略时应优先考虑线性和指数模型。人们会问这样一个问题：以绝对单位 (如欧元、美元、专利数量) 表示的影响或以现值百分比表示的相对增加是否更有意义。

以另一种方式考虑因变量有时会有所帮助。例如，如果因变量是一篇文章收到的引文总数，作为发表后年份的函数 (Antonakis 等，2014) 或其他累积函数，将累积率 (即，一篇文章每年被引用的次数) 而不是总引用次数进行理论化，然后通过考虑累积率作为自变量的函数是如何发展的，从而得出函数形式，这可能是有用的。

这同样适用于所有是一些较小组件的集合的因变量。在概念层面上指定形式后，需要将其形式化为函数，同时考虑函数的组合是可能的。不同的函数组合可以通过使用统计软件甚至 Excel 可视化来进行实验，以查看它们与概念派生形式的映射情况。

实证中确定函数形式的策略。如果没有理论上的建议，应该测试什么样的关联？在这种情况下，应根据数据经验选择函数形式。为此，我们提出了三种策略。第一种策略是以图形方式检查变量之间的关系。一种方法是使用分格散点图，首先将数据沿 x 变量分成大小相等的组，然后在散点图中使用 x 和 y 的组平均值。这个工具很容易操作，即使从大量观察中也能理解并有效揭示函数形式。

第二种策略是从线性回归模型开始，对非线性进行诊断。残差与拟合图可用于评估对非线性模型的总体需求，部分回归或添加变量图可用于评估个体模型的函数形式变量。我们不详细讨论它们，只关注它们如何应用于我们的实证例子。

* Figure 2: Residual vs. fitted plots and added-variable plots for linear 
* regression with normal and log transformed dependent variable

. estimates restore m1
. rvfplot, name(Figure2a, replace) title("Residual vs. fitted")
. avplot educat, name(Figure2b, replace) title("Added-variable: Education")
. avplot percwomn, name(Figure2c, replace) title("Added-variable: Women")

. estimates restore m2
. rvfplot, name(Figure2d, replace) title("Residual vs. fitted")
. avplot educat, name(Figure2e, replace) title("Added-variable: Education")
. avplot percwomn, name(Figure2f, replace) title("Added-variable: Women")

. graph combine Figure2a Figure2b Figure2c Figure2d Figure2e Figure2f, ///
>    rows(2) name(Figure2, replace)
. graph drop Figure2a Figure2b Figure2c Figure2d Figure2e Figure2f

图中的第一行曲线图显示了线性模型的残差与拟合曲线图和两个附加变量曲线图。残差与拟合图显示，小预测值和大预测值的残差均大于平均值，表明非线性模型优于线性模型。

添加的变量图表示一些二元非线性。特别是对于教育价值的大小，观察结果往往高于回归线。第二行图对应于具有对数转换因变量的模型。残差与拟合图现在显示了线性关系，添加的变量图没有显示任何主要的非线性，表明转换有效地解决了非线性问题。

即使使用原始线性模型而不是非线性模型，也应进行这些诊断并报告，以提供所选线性函数形式正确的证据。不需要详细的报告，但研究人员至少可以简单地陈述以下内容：“所有模型都是使用图诊断为异方差、非线性和异常值。没有发现任何问题。” 不幸的是，这样做并不常见。

第三种策略是用不同的函数形式拟合模型，并比较它们对数据的解释程度。例如， DeOrtentiis 等人 (2018 ) 采用了这一策略，他们使用幂项来测试时间的非线性效应，并将结果与从线性模型获得的结果进行比较。利用我们的示例数据，可以使用 $R^{2}$ 统计比较上表中模型 1 和模型 2 中使用的线性和非线性规范。

非线性模型的 $R^{2}$ 越高，表明它对数据的拟合越好。另一种方法是使用重置测试，将自变量的幂添加到模型中，以检测任何遗漏的非线性。然而，这种策略的缺点是研究人员必须指定要比较的函数形式，因此不可能进行全面的探索性分析。

总结：研究人员没有在假设中明确说明关系的函数形式并仍然应用非线性模型进行测试不能被视为方法学问题，而是管理理论或其测试方式不精确的结果。理想情况下，研究人员应根据什么样的效应具有理论意义，在假设中陈述预期的函数形式。

如果理论无法提供这种精度，则应根据模型在目视检查中与数据的拟合程度，或在适当情况下使用拟合统计比较模型，来选择函数形式。不幸的是，这是一个整体评估，不能浓缩成一个简单的规则。如果函数形式是根据经验确定的，则将其作为探索性分析报告很重要。

事实上，将函数形式及其解释引入理论可以被视为一项重要的理论贡献。即使研究人员无法解释所识别的函数形式存在的原因，这种观察也可以启发未来的工作，以理解为什么会观察到给定的函数形式。

3.2 建议 3：不要转换因变量，使用 GLM

由于两个原因，转换的因变量不是一种理想的方法。

首先，为了解释结果，需要将模型的预测转换回原始度量。在对数变换的情况下，这是通过使用指数函数实现的。然而，对数的平均值并不等于平均值的对数，这适用于所有非线性变换。

下图显示了男女主导职业的收入分配情况。将原始平均数与反向转换为原始指标的记录收入平均数进行比较，表明转换后的变量低估了平均数。男性占主导地位的职业的影响更大，这导致低估了这两个群体之间的差异。

* Figure 3: Comparison of mean of transformed variable
. summarize income if percwomn>50
. scalar women = r(mean)
. summarize lnincome if percwomn>50
. scalar womentransformed = exp(r(mean))
. summarize income if percwomn<50
. scalar men = r(mean)
. summarize lnincome if percwomn<50
. scalar mentransformed = exp(r(mean))

. twoway kdensity income if percwomn>50 || kdensity income if percwomn<50,      ///
>     legend(order(1 "More than half women" 2 "Less than a half women")         ///
>     ring(0) position(1) rows(2)) xline(`=women', lcolor(navy) lpattern(dash)) ///
>     xline(`=womentransformed', lcolor(navy) lpattern(dot)) ///
>     xline(`=men', lcolor(maroon) lpattern(dash))           ///
>     xline(`=mentransformed', lcolor(maroon) lpattern(dot)) ///
>     name(Figure3, replace)

其次，转换因变量的方法笨拙。也许最常见的方法是在 taking logs 之前 +1。其理由是：对数不是为零定义的，且大于或小于 1 的数字的工作方式不同。如果所有值最初都是非负的，这种转换使所有值大于等于 1。

另一种解决方法 (尽管不太常见) 通过使用修正来解决背部变形引起的偏差。这些方法是必需的，因为转换的因变量的线性模型虽然常见，但并不是将因变量建模为自变量的非线性函数的理想方法。

带有 log link 的 GLM 避免了因变量 log 转换所引起的问题。特别是，泊松回归产生了指数模型的一致估计，无论误差项的分布如何，其甚至可以用于非计数数据。Stata 的创始人William Gould (2011) 在一篇非技术性博客文章中阐述了这一点。当泊松回归应用于非计数变量时，似然统计将不正确。因此，这种方法被称为准最大似然 (QML) 估计。由于 QML 似然值不是适当的似然值，因此它们不能用于模型测试，但可以使用稳健的标准误差进行正确的推断。

为了证明 Poisson QML 比手动转换因变量更有效，我们将这两种技术应用于 Prestige 数据集，如上表中的模型 2 和 3 以及下图所示。

该图显示了两条曲线，一条基于 GLM 模型的预测，另一条使用转换后的因变量，按照当前建议反变换为原始比例。GLM 曲线穿过数据的中间部分，因此比使用转换的因变量的曲线拟合更好，后者往往低估数据的平均值，尤其是对于较大的值。作为一个额外的优势，常用的统计软件将自动正确地绘制 GLM 模型，而无需手动指定反向转换。

* Figure 4: Comparison of marginal predictions from normal linear model using
* log transformed dependent variable and Poisson QML model. 
. estimates restore m3
. margins, at(educat=(6(.2)16)) saving(mar3, replace)
. combomarginsplot mar2 mar3, noci plotopts(msymbol(none))           ///
>     addplot(scatter income educat, below mcolor(black)             ///
>     msymbol(circle_hollow) legend(order(1 "Transformed" 2 "GLM"))) ///
>     legend(ring(0) position(11) rows(2))                           ///
>     name(Figure4, replace)

总之，GLM 在统计学和实践上都是转换因变量的最佳选择。预测曲线更接近数据的中间部分，现代统计软件自动正确构建调整后的预测图，并且消除了笨拙的变通方法的需要。

然而，如前一指南所示，将 OLS 回归与转换的因变量结合使用可用于诊断目的。虽然在技术统计文献中已经知道泊松回归可以用于此目的，但其在研究实践中的应用一直很缓慢。一个可能的原因是制度化的想法，即这些模型应 (仅) 用于计数。

正如 Nichols (2010 ) 所指出的：“如果你决定使用 log link，您可能希望将你的模型称为 ‘带有 log link 的 GLM’，而不是 ‘Poisson’ QMLE。有人认为 Poisson 回归仅适用于计数。”

3.3 建议 4：首先选择 GLM 作为联系函数，然后转换自变量

由于 GLM 比转换因变量更可取，因此指定非线性模型可简化为两个决策：是否使用 GLM 和是否转换任何自变量。第一个决定更重要，因为它决定了自变量如何共同影响因变量。我们现在将讨论这个问题，这需要理解加法 (线性) 和乘法 (指数) 模型之间的区别。

为简单起见，我们将重点放在两个自变量 $x_{1}$ 和 $x_{2}$ 的情况下，并且仅适用于线性和指数情况：

Linear：

y = b_{0} + b_{1} x_{1} + b_{2} x_{2} + u

Exponential (GLM)：

y = e^{b_{0} + b_{1} x_{1} + b_{2} x_{2}} + u = e^{b_{0}} e^{b_{1} x_{1}} e^{b_{2} x_{2}} + u

这两种模型之间的一个重要区别是，在线性模型中， $x_{1}$ 和 $x_{2}$ 的影响相加，而在指数模型中 (例如，泊松回归 )，它们相乘。也就是说，在线性模型中，改变 $x_{1}$ 的效果总是相同的，而与 $x_{1}$ 和 $x_{2}$ 的当前值无关。然而，在指数模型中， $x_{1}$ 的影响与预测的 $y$ 成正比，因此取决于 $x_{1}$ 和 $x_{2}$ 。

加法模型和乘法模型之间的选择应该由理论驱动。例如，如果一项研究调查了一项全国性政策 ( $x_{1}$ ) 对新成立公司数量 ( $y$ ) 的影响，则该影响不应该对所有国家都相同，而应该与人口规模 ( $x_{2}$ ) 相关，这表明了一个乘法模型。

换言之，以一种全新的方式实施该政策与在小国实施这项政策相比，大国应该产生更多的新公司。相反，如果一个模型模拟了研发补助金 ( $x_{1}$ ) 对一家公司获得的专利数量 ( $y$ ) 的影响，那么加法模型将是合适的。

如果两个不同规模 ( $x_{2}$ ) 的公司获得了类似规模的资助，并且研发没有大规模经济，那么两个公司都应该使用该资助获得同等数量的研发工作，从而从该工作中获得大致相当数量的专利。因此，这种影响应该与决定一家公司获得多少专利的其他变量相加。

在某些情况下，可能需要结合线性和指数效应。例如，如果将研究人员的出版物总数建模为时间的函数 ( $x_{2}$ )，则个人的总体生产力可以是技能的指数函数 ( $x_{1}$ )，但出版物的数量 ( $y$ ) 随时间线性增加，而不是指数增加。在这里，技能和时间的影响显然是相乘的，但时间本身的影响是线性的，而不是指数的。GLM 框架提供了两种建模这种效果组合的替代方法：

Linear with interaction：

y = b_{0} + b_{1} e^{x_{1}} + b_{2} x_{2} + b_{3} x_{2} e^{x - 1} + u

Exponential：

y = e^{b_{0} + b_{1} x_{1} + b_{2} l o g x_{2}} + u = e^{b_{0}} e^{b_{1} x_{1}} {x_{2}}^{b_{2}} + u

下图中展示了这些规范。我们使用 Prestige 数据集估计了女性的线性效应 ( $x_{2}$ ) 和教育的指数效应 ( $x_{1}$ ) 对收入的影响。第一个规范是有问题的，因为指数效应 $e^{x_{1}}$ 的形状不是根据数据估计的。也就是说，与 16 年教育 (最高) 相比，6 年教育 (最低) 的 $b_{1} e^{x_{1}} + b_{3} x_{2} e^{x_{1}}$ 要大 22000 倍。

此外，教育对各级妇女的影响程度是相同的，妇女主要影响指数增长开始的基础水平，如下图的第一个图所示。

第二种规范更具吸引力，但添加 $l o g x_{2}$ 不足以模拟线性效应；我们必须进一步将系数 $b_{2}$ 限制为 $1$ ，从而产生：

Exponential with exposure：

y = e^{b_{0} + b_{1} x_{1} + l o g x_{2}} + u = e^{b_{0}} e^{b_{1} x_{1}} x_{2} + u

以这种方式约束的记录变量称为暴露变量 (exposure variable)，它作为乘数进入回归方程，从而刻画与暴露变量成正比的效应。暴露变量的使用在组织研究中并不常见，但它们在流行病学中很常见。在流行病学中，研究人员可能对哪些因素影响一个国家的疾病病例数感兴趣。

由于各国的人口数量各不相同，每个国家都有不同数量的人可能接触到某种疾病并成为病例。在这种情况下，我们将使用一个国家的人口数量作为暴露变量，预期病例总数为个人风险 (方程中的 $e^{b_{0}} e^{b_{1} x_{1}}$ )) 乘以用作暴露变量的人口规模 (方程中的 $x_{2}$ )。

在组织环境中，这些模型提出了一个引人注目的改变，即对规模效应进行控制，通常通过使用焦点变量 (focal variable) 和规模变量的比率 (例如，资产收益率=净收入/总资产) 作为因变量进行控制。曝光模型的可视化为上图中的第二个图。在这个模型中，指数增长的幅度 (曲线形状 ) 是根据数据估计的，从而得出一个更为渐进的估计，其中基础水平和由于教育而增加的幅度随着妇女所占份额的变化而变化。

总结：指定模型时的第一个决定是确定模型中的变量是以相加方式组合还是以乘法方式组合。在线性加性效应模型中每个自变量的影响是绝对的，不依赖于模型中的任何其他变量。在指数乘性效应模型 (如泊松回归) 中，效应始终相对于所有自变量的当前值，通常以百分比表示。在实践中，选择是是否使用 GLM 以及使用哪一个 link 函数，该选择传统上是根据因变量的分布来确定的。相反，我们认为理论应该在这个选择中扮演更重要的角色。前面思维实验策略的解释在这里也很有用。

3.4 建议 5：基于一致性而不是模型适用选择 GLM 分布

GLM 规范涉及两个关键决策：选择自变量与因变量期望值之间关系的 link 函数以及因变量的 (条件) 分布。重要的是，分布与一组特定预测变量的条件分布有关，而不是在研究的数据准备和筛选阶段分析的无条件分布。

其中，第一个决定更为重要，因为它决定了估计的函数形式；第二个决定只影响所选形式是否正确估计。不幸的是，鉴于目前的指导方针以 (无条件) 分配为出发点，并且在很大程度上忽略了讨论，因此学科中形成了完全相反的决策过程。

如何选择 (有条件的) 分布？由于分布代表模型之外的变量引起的因变量变化，因此根据理论很难激励分布的选择。因此，问题就变成了如果所选择的分布事实上可能不正确，应该采用哪种分配方式？GLM 模型采用最大似然估计进行估计，如果正确指定模型，则该估计已被证明是一致且渐近有效的，包括因变量的正确 (条件) 分布。

不幸的是，最大似然估计通常对分布的错误指定不鲁棒，并且变得不一致。但幸运的是，这条规则也有例外。这方面的一个例子是线性回归，它假设误差项为正态分布，但如前所述，如果模型被正确指定，则可以很好地处理任何分布。

对于指数模型，泊松分布已被证明可以产生一致的估计，而不管实际分布如何，甚至可以用于非计数数据。如果模型使用 logit 曲线，我们可以使用伯努利分布获得相同的效果，数据不需要是二进制的，也可以是分数 (即在 [0,1] 范围内)。在这些情况下，估计值为 QML，必须使用异方差一致 (稳健) 标准误差。

当前在泊松回归和负二项回归之间进行选择的做法是估计两个模型，并通过似然比检验选择最佳拟合模型。这个规则有潜在的问题：负二项回归是一种安全的选择，当因变量 (有条件地依赖于独立变量) 的分布为泊松分布或泊松过度分散时，负二项回归可能更有效。

在其他情况下，负二项回归可能不一致，不应使用。使用似然比检验来确定使用哪种分布是因为测试没有提供证据证明负二项分布是正确的，只是数据更可能来自负二项分布而不是泊松分布。因此，负二项分布的使用应限于有充分的理论理由相信该分布是正确的，且应使用泊松分布作为默认替代由于泊松分布具有更普遍的一致性。

总之，在使用 GLM 时，研究人员需要选择一个 link 函数，该函数描述自变量如何与因变量的预期值相关，以及因变量在预期值周围的 (条件) 分布。第一个决定应该基于理论，或者，如果理论没有提供足够的指导，则应该基于经验确定的关系。选择在模型中使用哪个分布会影响分析的稳健性和效率。

在使用 log link 的模型中，泊松分布已被证明能产生一致的估计，在使用 logit link 的模型，伯努利分布也被证明了这一点。鉴于一致性是估计结果的最重要特征，这两种分布应优先于负二项 (log link) 或 gamma (logit) 分布，除非有强有力的理论理由相信所选分布适用于数据。两个模型之间的似然比检验不能提供这一信息。

3.5 建议 6：当建模 U 型和其他曲线效应时，要考虑不同的替代

将平方自变量添加到模型中是当前组织研究中建模非线性关系的主要做法。因此，有一种常见惯例，即应通过向模型中添加幂项来测试非线性效应，且幂项应仅用于此目的。

几乎完全使用幂项是有问题的，因为它可能导致对 U 型效应的错误推断。幂项假设了一种特定形式的非线性 (抛物线开口向上或向下)，如果这种形式不适合数据，则可能导致对 U 型效应的错误推断。

例如，将抛物线拟合到数据集，其中 $y = l o g x$ 将错误地指示存在 U 型 (先向上，然后向下，或相反) 效应。如果 y 先逐渐增加，然后急剧下降，则可能得出相反的错误结论，即增长趋势。我们在下图中第一个图中显示了这种效果，其中显示了 binned 散点图和由 binsreg 命令生成的二阶多项式曲线，以及拟合泊松 QML 回归的指数曲线供参考。

由于 U 形曲线的拐点在数据范围内，我们可以得出以下结论：教育对入学前 8 年的收入有负面影响，这听起来不现实。

* Figure 6: Binned scatterplot matrix and spline regression for discovering 
* functional form. We use the user-written binsreg command to combine the two
* sets of adjusted predictions. We use the user-written addplot command to 
* add the scatterplot of the data under the bin scatter plot. To install, type
* ssc install binsreg
* ssc install addplot
. binsreg income educat, polyreg(2) ///
>    bycolors(maroon) title("Binscatter plot and polynomial") ///
>    name(Figure6a, replace)
. addplot: (scatter income educat, mcolor(black) ///
>    msymbol(circle_hollow) below)

* Add adjusted predictions from the Poisson QML model
. preserve
. use mar3, clear
. addplot: (line _margin _at1, lcolor(navy))
. restore

* We use the non-linear least squares function to calculate the spline. We 
* estimate an intercept b0, three regression coefficients b1-b3, and two
* positions for the knots. The idea is that the effect of education depends
* on education itself so that the effect is

* education < c1: b1
* c1 < education < c2: b1 + b2
* c2 < education     : b1 + b2 + b3

* To implement this, we multiply the regression coefficient b2 by the positive
* difference between education and c2 and the coefficient b3 by the positive 
* difference between education and c3.

. nl (income = {b0} + {b1}*educat + {b2}*max(educat-{c1}, 0) + {b3}*max(educat-{c2}, 0)),  ///
>    variables(income educat)  /// Use rough guesses as starting values
>    initial(b0 1400 b1 400 b2 1000 b3 4000 c1 9 c2 14)
. margins, at(educat=(6(.1)16))
. marginsplot, noci plotopts(msymbol(none))              ///
>    addplot(scatter income educat, below mcolor(black) ///
>    msymbol(circle_hollow)) legend(off)                ///
>    name(Figure6b, replace)
. graph combine Figure6a Figure6b, name(Figure6, replace)
. graph drop Figure6a Figure6b

虽然指数模型显然是模拟教育对收入的非线性影响的更好的选择，但它不是一个普遍的解决方案；指数形式是一种特殊形式，它可能无法很好地拟合所有数据，并且不能像幂项一样用于测试 U 形效应。

回归样条曲线为非线性效应建模提供了另一种方法。这里的想法是拟合一个具有一个或多个节点的线性模型，其中回归线的方向发生变化。对样条曲线回归的深入解释超出了本文的范围，但我们请读者参考 Edwards 和 Parry (2018) 了解详细信息。

上图中的第二个曲线图显示了一个样条回归，其中两个节点是根据数据估计的。我们选择使用两个 knot，因为我们假设教育的影响可能在初等教育之后增加，在大学进一步增加。然而，这一假设并不被实证支持，因为在 plot 的方向上只有一个明显的变化。这表明教育对中小学教育的影响是稳定的，之后影响急剧增加。样条曲线模型也比指数曲线或多项式曲线更适合高等教育职业。

综上所述，目前在组织研究中评估非线性效应的主流做法是在模型中加入自变量的二次幂。尽管这种方法在检测是否存在非线性方面很有用，但对于检测数据中存在何种非线性可能并不理想，并且可能导致错误的解释。代替常规的幂项的应用，我们建议研究者还考虑其他变换，例如依赖变量的对数变换或 GLM 或使用回归样条，这为非线性效应的建模提供了一种灵活的替代方案。

4. 对理解使用转换的模型的建议

我们的研究表明，非线性模型通常被解释得不完全甚至不正确。这是一个主要问题，因为焦点变量之间关系的形式和强度应该是主要的理论关注点。因此，我们提出两条改进理解和报告做法的建议。

4.1 建议 7：通过绘图来理解非线性效应，包括置信区间和数据

线性模型的解释很简单：当自变量增加一个单位时，回归系数给出了因变量的预期增加，并且这种影响在自变量范围内是恒定的。非线性模型的情况更复杂。因为将自变量更改一个单位会导致因变量发生不同的绝对变化，这取决于因变量、自变量或两者的当前值。

因此，有几种不同的解释技术。最常见的策略是简单地观察 $p$ 值和系数的符号来推断效应的方向，忽略关系的强度和形式。第二种最常见的方法是使用预测图，但这主要是由使用包含作为自变量的相互作用或功率。接下来我们将详细讨论不同的解释技术。

基于数字的解释：指数模型可以方便地解释为当自变量增加一个单位时，因变量相对于其当前值的变化百分比，如下表所示。当百分比变化很小时，这种方法效果很好，但在回归系数为 0.3 时，近似值 (30%) 与指数模型结果 (1.35) 之间的差异为 5 个百分点 (Wooldridge，2013)。

另一种方法是对系数进行指数化 (即，解释 $e^{b}$ 而不是 $b$ ) ，这可以解释为百分比变化或比率。如果解释为百分比变化，则指数化系数可以更准确地估计一个单位的正变化，而牺牲了可比负变化的准确性。因此，如果需要百分比变化解释，应首选近似解释，除非有充分理由只关注自变量的正向变化。

当解释为比率 (例如，发病率比率、优势比) 时，指数系数表示因变量随着自变量的变化而被乘 (正效应) 或除 (负效应)。例如，比率 2 表示正面效应增加 100% 或负面效应减少 -50%。

最常见的基于比率的解释是使用 logistic 回归的 odds ratio。不幸的是，他们的解释并不容易。最常见的错误是将 odds ratio 解释为概率的变化。这通常无法做到，因为概率取决于基本概率。此外，除非模型中包含所有相关自变量，否则 logistic 模型的参数估计以及 odds ratio 都是 negatively biased。

报告 APE 或 AME 是一种可以适用于所有非线性模型的理解策略。在这种方法中，我们对每一个观察估计预测的边际效应——当自变量变化很小时因变量的预期变化，并报告平均值。该策略本质上表达了一种类似一个单一的线性效果的非线性效果，并倾向于产生与线性模型非常类似的结果。然而，尽管它简化了解释，它也使得这种方法很难 justify。如果需要线性解释，首先使用线性模型将是一个更简单的解决方案。

基于绘图预测的解释：计算和绘制预测是一种通用策略，可用于所有非线性模型。预测可以通过两种不同的方式进行计算：调整预测 (有时指作为预测利润或循环预测) 和平均值预测。

计算调整预测包括通过改变一个或多个自变量并保持另一个自变量的观测值，使用估计模型计算因变量的预测值。平均值预测包括首先计算模型中的每个变量的平均值，然后计算所有变量的预测值平均值。两种预测之间的差异方法可以通过一个例子来理解。

下包显示了一个样本的教育数据，由五男五女组成。我们想计算 6 至 16 岁之间六种不同水平的教育的预测。通过调整预测，我们首先将原始教育值替换为 6，然后计算每个人的预测值，然后对所有观察值取平均值。这将对所有教育水平重复，以获得六个平均调整预测。当以平均值进行预测时，我们只会为一个教育水平计算一个假设的人的一个预测值，假设的人是半个男人和半个女人。虽然这两种预测在线性模型中是相同的，但在非线性模型中却不同，结论也可能不同。

计算平均值时的效应也隐藏了这样一个事实，即非线性效应在自变量的不同值时可能会有很大的不同。考虑下面的模型：

Linear：

y = a + b_{1} x + u

Exponential：

y = e^{a + b_{1} x} + u = e^{a} e^{b_{1} x} + u

Logit：

y = l o g i s t i c (a + b_{1} x) + u

其中 x 是感兴趣的变量，a 是所有其他变量和截距的影响。在线性模型中，a 仅表示一组平行线的截距，显示 x 的恒定效应。相反，在指数模型中，a 的影响不是加性的，而是乘性的。

在 logit 模型中，a 表示沿 logistic 曲线 (逆 logit) 观察开始的距离。如果观测值位于曲线相对平坦的部分，x 的边际效应很小，但在曲线陡峭的中间部分情况就不同了。下图显示了 x 对不同 a 值的影响。因此，重要的是在不同的变量值 (而非感兴趣的变量值) 绘制边际预测。

对绘图实践的改进：除了显示函数形式外，还必须显示估算的精度，并提供所选形式与数据相符的证据。置信区间可包括以完成第一项任务。为了支持所选择的函数形式，我们建议研究人员不仅可视化预测曲线，而且通过绘制案例或 (如果因案例数量较多而不可能) 使用 rug 和等高线图来指示其数据在同一图中的位置，如下图的第一个图所示。

等高线图使用一组嵌套的简单闭合曲线显示观测值位于图的哪些部分 (密度较高)。最内侧的曲线显示了观测值最多的绘图区域部分，当向外侧曲线移动时，观测值会变得更稀疏。地毯图通过使用轴上的小刻度指示观察值如何沿每个变量分布。这可能是有用的，因为它指示每个变量的范围和分布，而不提供关于特定变量组合的任何可能是机密的信息。

当单个变量很好地解释了两个变量之间的模式时，将调整后的预测曲线叠加在数据上效果很好，但在其他情况下可能不那么有效。下图的第二个曲线图显示，调整后的预测曲线无法解释数据井中的模式。为了更好地显示这种效果，我们可以通过 prestige 将数据集划分为五个分位数，并分别绘制每个子样本的预测曲线。由此产生的五条曲线表明，该模型确实很好地解释了数据，尽管教育的效果并非人们所期望的那样。

* Figure 8: Adjusted prediction plot of Poisson QML model with contour plot
* indicating density and rug plots instead of the raw data
* First panel: The fitted model
* We use the bidensity command to do a contour plot and then add the marginal
* predictions using addplot.
* To install the commands, type
* ssc install moremata
* ssc install bidensity

. estimates restore m3
. margins, at(educat=(6(.2)16))
. marginsplot, plotopts(msymbol(none))  ///
>    recastci(rarea) Confidence band    ///
>    ciopts(fcolor(%15) lwidth(none))   /// Adjust the look of the band
>    name(Figure8a, replace)

* Save the two-dimensional density and add it as contour line plot
. bidensity income educat, n(25) kernel(gaussian) nograph ///
     saving(den, replace)
. preserve
. use den, clear
. addplot: (contourline _d _income _educat, levels(10) below)
. restore

* Add the rug plots
. gen y = -1000
. gen x = 16.5
. addplot: spike y educat, lcolor(black)
. addplot: spike x income, lcolor(black) base(16.7) horizontal ///
     xlabel(6(2)16) ylabel(0(5000)25000) ///
     legend(order(1 "Transformed" 2 "GLM"))
. drop x y

* Second panel, a model where the effect of education is not significant after
* controlling for prestige
* Margins for subgroups

. xtile prestigeGroup = prestige, n(5)
. estimates restore m4
. margins, at((min)educat) ///
>    at((p10)educat)       ///
>    at((p20)educat)       ///
>    at((p30)educat)       ///
>    at((p40)educat)       ///
>    at((p50)educat)       ///
>    at((p60)educat)       ///
>    at((p70)educat)       ///
>    at((p80)educat)       ///
>    at((p90)educat)       ///
>    at((max)educat)       ///
>    over(prestigeGroup) saving(mar4, replace) 

* Margins for full data. We trick Stata by changing the group
. replace prestigeGroup = 6
. margins, at(educat=(6(.2)16)) saving(mar5, replace) over(prestigeGroup) 

. combomarginsplot mar4 mar5, plotopts(msymbol(none) lcolor(navy)) ///
>    recastci(rarea)                      /// Confidence band
>    ciopts(fcolor(navy%15) lwidth(none)) /// Adjust the look of the band
>    xdimension(at(educat)) plotdimension(prestigeGroup) ///
>    /// No CIs and different color for the full data line
>    plot6opts(lcolor(maroon)) ci6opts(fcolor(none))     ///
>    legend(ring(0) position(11) rows(2))                ///
>    name(Figure8b, replace)
	
* Add the previously saved two-dimensional density as contour line plot
.preserve
.use den, clear
.addplot: (contourline _d _income _educat, levels(10) below)
.restore

* Add the rug plots
. gen y = -1000
. gen x = 16.5
. addplot: spike y educat, lcolor(black)
. addplot: spike x income, lcolor(black) base(16.7) horizontal ///
>    xlabel(6(2)16) ylabel(0(5000)25000)                       ///
>    legend(order(12 "Full data" 11 "Prestige subgroups"))

. drop x y prestigeGroup
. graph combine Figure8a Figure8b, name(Figure8, replace)
. graph drop Figure8a Figure8b

总之，我们建议使用调整后的预测 (而不是平均预测) 来解释非线性模型。作为一种图形解释技术，这种方法产生的结果更容易解释 (与指数系数相比)，并且更清晰呈现非线性效应的性质 (与 APE/AME 等相比)。尽

管之前的研究要求对特定类别的非线性模型进行图形化解释，但我们将此建议扩展到所有非线性模型。这些曲线图应显示置信区间，并指示观测的位置。这将为非线性函数形式的适当性以及效应的大小提供证据。

4.2 建议 8：不要从交互作用而是从图中推出适度

使用非线性模型测试适度假设 (moderation hypotheses) 需要特别小心，因为在这些模型中使用交互作用可能会产生令人困惑的结果。Murphy 和 Russell (2017 声称 “不恰当地使用转换” 是产生小调节效应的原因之一。

在管理研究中，问题不是转换的不当使用。相反，这是对建模结果的不恰当解释。通常，人们将检查相互作用项的统计显著性。如果不显著，人们会得出结论，没有人支持缓和效应，结果也不会被进一步解释。然而，仅检查互动就提供了关于适度的误导理解。

为了讨论适度测试，我们需要首先定义什么是适度。不幸的是，这个概念本身的定义往往不准确。例如，Dawson (2014) 指出：“In general terms, a moderator is any variable that affects the association [emphasis added] between two or more other variables; moderation is the effect the moderator has on this association” (P1)。

这一定义是有问题的，因为定义 association 的主要假设通常未定义其形式 (例如，线性、指数)，导致调节效应的确切含义相当模糊。例如，考虑以下假设：

假设 2 ：教育对收入的积极影响受女性比例的调节；对于女性较少的职业，这种影响更大。

假设一个典型的男人和女人分别挣 6000 美元和 4000 美元。如果一个典型的男人多上学一年，他应该期望工资增加 600 美元或 10%。现在，考虑一个典型的女人在三种情况下的相同效果，分别对应 400 美元、500 美元和 600 美元，以及加薪幅度 10%、12.5% 和 15%。

在这三种情况下，教育对两性都有积极的影响，但这种影响是否受到性别的调节，如果是，是向哪个方向调节？除非人们愿意采用特定的功能形式，否则这个问题的定义是错误的。答案取决于研究者是对百分比增长 (指数曲线) 还是绝对增长 (线性模型) 感兴趣。特别是，在第二种情况下 (女性为 500 美元或 12.5%)，性别的调节效应甚至会有不同的迹象 (女性为 100% 比 2.5% 多)，这取决于所选择的功能形式 (即绝对效应与相对效应)。

函数形式的影响上表中最后两个回归模型所示。线性模型 5 具有显著的相互作用项，而在非线性模型 6 中，相互作用项不显著。然而，下图显示了一个明显的调节效应，如果考虑到绝对收入：在这两个图中，教育对男性占主导地位的职业的影响要大得多。这也说明了绘制数据有助于选择模型的原因：线性模型明显地外推了数据，低估了高等教育职业的收入，尤其是那些女性较多的职业，因此与非线性模型不匹配。

* Figure 9: Comparison of marginal predictions from normal linear model and Poisson
* QML model when both models contain an interaction between gender and education
* First plot: Linear model

. estimates restore m5
. margins, at(educat = (6(.2)16) percwomn =(0 25 50 75 97.5))
. marginsplot, plotopts(msymbol(none)) ///
>    recastci(rarea)                   /// Confidence band
>    ciopts(fcolor(%15) lwidth(none))  /// Adjust the look of the band
>    addplot(scatter income educat [w=percwomn], msymbol(>circle_hollow) ///
>    msize(vsmall) mcolor(black) below      ///
>    legend(title("Share of women") rows(3) ///
>    order(6 "0%" 7 "25%" 8 "50%" 9 "75%" 10 "97.5%"))) ///
>    legend(ring(0) position(11))                       ///
>    note("Size of circles indicate the share of women") name(Figure9a, replace)

* Second plot: GLM
. estimates restore m6
. margins, at(educat = (6(.2)16) percwomn =(0 25 50 75 97.5))
. marginsplot, plotopts(msymbol(none)) ///
>    recastci(rarea)                   /// Confidence band
>    ciopts(fcolor(%15) lwidth(none))  /// Adjust the look of the band
>    addplot(scatter income educat [w=percwomn], msymbol(circle_hollow) ///
>    msize(vsmall) mcolor(black) below                  ///
>    legend(title("Share of women") rows(3)             ///
>    order(6 "0%" 7 "25%" 8 "50%" 9 "75%" 10 "97.5%"))) ///
>    legend(ring(0) position(11))                       ///
>    note("Size of circles indicate the share of women") name(Figure9b, replace)

.graph combine Figure9a Figure9b, name(Figure9, replace)
.graph drop Figure9a Figure9b

为什么不需要互动效应来推断适度？原因是，在指数模型中，如前所述，效应是乘性的，而不是加性的。因此，缺乏一个重要的互动术语并不意味着绝对意义上不存在调节效应；它只是以另一种形式呈现，如上图所示。

类似地，如果数据的适当模型是指数模型，那么拟合线性模型可以产生指数模型中不存在的显著交互作用。这是一种与非线性相互作用的混淆形式。同样的逻辑也适用于逻辑模型，即使模型中没有交互作用，也可能存在调节效应。在某些情况下，logit 和线性模型甚至可以产生不同符号的交互系数。绘制效果图也可以解决这些明显的矛盾。

我们是否应该将上图解释为支持适度效应？理想情况下，适度假设的表述方式应不留任何模棱两可的余地。如果我们假设教育对收入的影响与当前收入水平相关，我们可以说明另一种更精确的缓和假设：

假设 2a：教育对收入的积极相对影响受女性比例的调节；对于女性较少的职业，这种影响更大。

上图所示的结果不支持假设 2a。尽管男性占主导地位的职业的收入绝对增长幅度更大，但研究结果并未表明教育会以不同方式增加男性和女性的收入。两者都经历了相同的相对效应，而绝对效应的差异仅仅是因为男性收入更高，而与受教育程度无关。

总之，非线性模型既不会隐藏也不会产生虚假的调节结果，尽管错误的解释可能会这样做。检验适度假设需要全面的解释，最好是通过绘图，而不仅仅是检查模型中交互项的重要性。

检验适度的一个关键问题是，主假设和适度假设通常不精确，缺乏预期的功能形式。这造成了歧义，因为在考虑绝对效应时可能存在适度，但在考虑相对效应时可能不存在适度，如我们的示例所示。也有可能是两种效应都有所缓和，但方向不同。为了解决这些问题，研究人员应该更全面地评估他们的模型，并通过观察曲线图的形状和比较它们与数据的匹配程度来解释结果。

5. 总结

我们认为，组织研究人员应该重新考虑他们对转换的使用。使用非线性模型或转换的决定不应基于单个变量的分布，但应基于自变量和因变量之间关系的预期函数形式，这反过来应基于理论。

因此，转换不应该归属于数据准备阶段，而应被视为研究设计的一个组成部分，与模型中的自变量的选择相一致。在这种背景下，最近关于使用转换变量测试假设会有问题的说法完全是不正确的。如果假设没有指定函数形式，那么任何单调形式都可以。不幸的是，尽管最近呼吁更精确的理论，但目前的理论仍然为确定函数形式提供了有限的支持。

我们的文章强调了三个关键问题。首先，变换经常被不必要地应用，或者至少有不正确的理由，例如与变量的非正态性有关，或者因为因变量是一个计数。其次，转换并不总是应用于它们应该应用的地方。这一点很明显，在构建假设时，函数形式考虑不足，并且忽略将提供给定函数形式证据的回归诊断似乎是规则而非例外。第三，转换产生的非线性模型常常被错误地解释。我们希望这些建议和实证例子将改进未来的研究实践。

6. 相关推文

Note：产生如下推文列表的 Stata 命令为：
lianxh 非线性对数, m
安装最新版 lianxh 命令：
ssc install lianxh, replace

专题	嘉宾	直播/回看视频
⭐ 最新专题		文本分析、机器学习、效率专题、生存分析等
研究设计	连玉君	我的特斯拉-实证研究设计，-幻灯片-
面板模型	连玉君	动态面板模型，-幻灯片-
面板模型	连玉君	直击面板数据模型 [免费公开课，2小时]