DID：仅有几个实验组样本的倍分法 (双重差分)

发布时间：2021-01-07 阅读 11176

Stata连享会主页 || 视频 || 推文 || 知乎

温馨提示： 定期清理浏览器缓存，可以获得最佳浏览体验。

New！ lianxh 命令发布了：
随时搜索连享会推文、Stata 资源，安装命令如下：
. ssc install lianxh
使用详情参见帮助文件 (有惊喜)：
. help lianxh

✌ 课程详情： https://gitee.com/arlionn/Course | lianxh.cn

✨ 课程主页： https://gitee.com/arlionn/Course

作者： 周涛 (华中师范大学)
邮箱： tzhou0806@163.com

编者按： 本文主要参考以下文献，特此致谢！

Source: Conley T G, Taber C R. Inference with “difference in differences” with a small number of policy changes[J]. The Review of Economics and Statistics, 2011, 93(1): 113-125. -Link-

1. 简介

在之前「倍分法DID」专题中，我们已经详细介绍过 DID 方法的使用和操作细节。本推文主要目的是，讨论该方法在使用过程中，当受外生冲击的处理组数量较少时，会对估计结果产生什么影响、以及应该如何处理。

我们使用 $N_{1}$ 来表示处理组的个数， $N_{0}$ 表示控制组（不受外生冲击的影响）的个数。一般而言，我们在使用 DID 估计中都会要求样本量足够大，这样估计出来的系数则更有效。但即使是大样本，也会出现受外生冲击的处理组 $N_{1}$ 较小的情况。

在此情况下，用于大样本的近似统计推断是不合适的。借鉴 Conley 和 Taber (2011)，我们可以使用来自 $N_{0}$ 个控制组的信息来一致地估计点估计量的分布，进而得到参数的真实值。

2. 理论推导

我们用简单的模型可以说明基本问题，及其解决方法：

Y_{j t} = α d_{j t} + θ_{j} + γ_{t} + η_{j t}

其中， $d_{j t}$ 表示政策变量， $α$ 是我们感兴趣的参数。 $θ_{j}$ 和 $γ_{t}$ 分别表示组别效应和时间效应， $η_{j t}$ 表示随机干扰项。假设只有一组 ( $j = 1$ ) 受到外生冲击，并且该冲击发生在 $t^{*}$ 期 ( $t = 1, . . ., T$ )，然后使用最小二乘法 (OLS) 估计上述模型。

${\hat{α}}_{F E}$ 是 $α$ 的估计值，那么：

\begin{aligned} {\hat{α}}_{F E} & = α + (\frac{1}{T - t^{*}} \sum_{t = t^{*} + 1}^{T} η_{1 t} - \frac{1}{t^{*}} \sum_{t = 1}^{t^{*}} η_{1 t}) \\ - (\frac{1}{(N - 1)} \sum_{j = 2}^{N} \frac{1}{(T - t^{*})} \sum_{t = t^{*} + 1}^{T} η_{j t} - \frac{1}{(N - 1)} \sum_{j = 2}^{N} \frac{1}{t^{*}} \sum_{t = 1}^{t^{*}} η_{j t}) \end{aligned}

在 $η_{j t}$ 满足零条件均值假设情况下 (mean zero conditional)， ${\hat{α}}_{F E}$ 是无偏的，但并不一致。随着组别数量的增大，等式最右边那一项近似为 0，即：

({\hat{α}}_{F E} - α) \overset{p}{\to} W \equiv [\frac{1}{T - t^{*}} \sum_{t = t^{*} + 1}^{T} η_{1 t} - \frac{1}{t^{*}} \sum_{t = 1}^{t^{*}} η_{1 t}]

换句话说， ${\hat{α}}_{F E}$ 估计量等于 $α$ 的真实值加上一个干扰项 $W$ 。由于样本的时间跨度 $T$ 和处理组的个数 $N_{1}$ 是固定的，因此，即使在大样本的情况下， $W$ 也不会消失。

通常，我们在进行实证研究时会忽视这个问题。如果经典线性回归模型是适用的，那么传统的方法也可以进行正确的小样本统计推断。但是在大多数情况下，由于 $η_{j t}$ 非正态性或者存在自相关的情况，经典线性回归模型是不适用的。

在 Conley 和 Taber (2011) 中，作者认为 ${\hat{α}}_{F E}$ 并不是一致估计量，但仍然可以使用 $η_{j t}$ 的分布来构造 $α$ 的置信区间。同时，控制组虽然不能提供关于 $α$ 的信息，但是这并不妨碍利用控制组残差 $η_{j t}$ 的信息来了解 $W$ 的分布情况。使用 ${\hat{η}}_{j t}$ 来表示残差估计值， ${\hat{W}}_{j}$ 表示残差的函数：

{\hat{W}}_{j} \equiv \frac{1}{T - t^{*}} \sum_{t = t^{*} + 1}^{T} {\hat{η}}_{j t} - \frac{1}{t^{*}} \sum_{t = 1}^{t^{*}} {\hat{η}}_{j}

当 $N_{1}$ 足够大时， ${\hat{W}}_{j}$ 与 $W$ 同分布。通过 ${\hat{W}}_{j}$ 的分布，可以构造出一个 $α$ 的置信区间。例如，在下图中，我们选取 $W$ 在 -0.11 到 0.09 之间的间隔，对应的大概就是 90% 的置信区间。

在之前的文献中，Moulton (1990)、Donald 和 Lang (2007) 分别讨论了 $N_{1}$ 和 $N_{0}$ 很大或很小的情况，Conley 和 Taber (2011) 对于 DID 中 $N_{1}$ 数量很少时的处理是在已有文献基础上，对方法的补充。

对于 $W$ 的分布，Conley 和 Taber (2011) 进一步研究得出，在满足 $N_{1} \to \infty : \hat{β} \overset{p}{\to} β$ 时，存在：

W = \frac{\sum_{j = 1}^{N_{0}} \sum_{t = 1}^{T} (T_{j t} - {\bar{T}}_{j}) (η_{j t} - {\bar{η}}_{j})}{\sum_{j = 1}^{N_{0}} \sum_{t = 1}^{T} {(T_{j t} - {\bar{T}}_{j})}^{2}}

其中，

\begin{aligned} {\tilde{Y}}_{j t} - {\tilde{X}}_{j t}^{'} \hat{β} & = {\tilde{X}}_{j t}^{'} (\hat{β} - β) + (η_{j t} - {\bar{η}}_{j} - {\bar{η}}_{t} + \bar{η}) \\ \overset{p}{\to} (η_{j t} - {\bar{η}}_{j}) \end{aligned}

{\tilde{Z}}_{j t} = Z_{j t} - {\bar{Z}}_{j} - {\bar{Z}}_{t} + \bar{Z}

3. Stata 范例

该方法被很多文献所应用，例如：

Cascio 等 (2013) 在研究奥巴马提出的 “全民学前教育” 项目对学前入学率的影响时，由于数据原因，仅将 Georgia 和 Oklahoma 这两个州作为研究的重点对象，Cascio 等 (2013) 在文中利用该方法计算出 Conley-Taber 置信区间。
Pinotti (2015) 在研究 20 世纪 70 年代意大利南部两个受到黑手党活动影响的地区战后经济发展情况时，将受黑手党影响之前和之后的普利亚和巴西利卡塔的地区经济发展与一个没有受到影响的区域进行了比较。在该分析中，也存在处理组个数较少的情况，Pinotti (2015) 参考了 Conley 和 Taber (2011)、Donald 和 Lang (2007) 进行了相应分析。
此外，Arindrajit 等 (2016)、Rockoff (2008)、coady 等 (2018)、Francesco (2014) 都使用到了该方法。

在本节中，我们将通过美国颁布的优秀学生教育奖学金项目 (HOPE) 这一实例，来展示 Conley 和 Taber (2011) 的应用。为了方便起见，这里仅将哥伦比亚特区作为我们研究的对象，并使用 41 个州 (40 个作为控制组的州 + 哥伦比亚特区) 的数据来研究 HOPE 对大学入学率的影响。结果如下图，在本节中我们主要讨论 Conley-Taber 置信区间的计算。

计算 Conley 和 Taber(2011) 置信区间的步骤如下：

将 $Y_{j t}$ 对 $X_{i}$ 和州-时间虚拟变量做回归；
将第一步中估计出的州-时间虚拟变量对 $d_{j t}$ 、 $θ_{j}$ 、 $γ_{t}$ 做回归；
得到 $\hat{α}$ 的估计量；
使用控制组的样本模拟出 $\hat{α}$ 的分布；
选取不能拒绝原假设的空集，作为 $\hat{α}$ 的置信区间。

相关 Stata 代码如下：

clear all
set more off
set matsize 800
set mem 200m
*数据下载地址：https://gitee.com/arlionn/data/blob/master/data01/reg.raw
infile coll hope male black asian year state using reg.raw

第一步，生成州-时间虚拟变量，并将 $Y_{j t}$ 对 $X_{i}$ 和州-时间虚拟变量做回归；

/* Create iteraction terms for years and states*/
gen styr=1000*state+year   //state-year dummy variable
sum state 
g stmin=r(min)
g stmax=r(max)
sum year 
g yrmin=r(min)
g yrmax=r(max)

/* Create dummies for state+year interactions*/
g yr=yrmin
quietly {
  foreach st of numlist 11/16 21/23 31/33 35 41/47 51/56 58 62 63 73 74 81/84 86 87 91/95 {
    while yr<=yrmax {
	local ind=`st'*1000+yr
	g byte Dstyr_`ind'=styr==`ind' 
	replace yr=yr+1
	}
   replace yr=yrmin
  } 
}

reg coll male black asian Dstyr*, noc r clust(styr)
predict colhat, xb
gen beta=colhat-male*_b[male]-black*_b[black]-asian*_b[asian]

/* Keep only beta coefficients for state*year terms */
collapse (mean) beta state year yrmin yrmax hope, by(styr)

xi: reg beta hope i.year i.state, robust
xi: reg beta hope i.year i.state, r cluster(state)

第二步，生成州和时间单独的虚拟变量 $θ_{j}$ 、 $γ_{t}$ ，将第一步中估计出的州-时间虚拟变量对 $d_{j t}$ 、 $θ_{j}$ 、 $γ_{t}$ 做回归；

/* Create state and year dummies*/
g yr=yrmin
quietly {
  while yr<=yrmax {
    local k=yr
    g byte Dyear_`k'=year==`k' 
    replace yr=yr+1
  }		
}

quietly {
  foreach st of numlist 12/16 21/23 31/33 35 41/47 51/56 58 62 63 73 74 81/84 86 87 91/95 {
    g byte Dstate_`st'=state==`st' 
  }
}

/* Now regress the coefficients (beta) obtained from the previous regression 
on state and year dummies and hope variable*/
reg beta hope Dstat* Dyear*, noc

/* Create an indicator for the state where policy changed (Georgia==1)*/
g byte ga=state==58    // ga = 1 表示受到影响的state

/* Predict residuals from regression */
predict eta, res    //估计 reg beta hope Dstat* Dyear*, noc 的残差

第三步，得到 $\hat{α}$ 的估计量；

replace eta=eta+_b[hope]*hope
drop D*

/* Create d tilde variable*/
bysort year: egen djtga=mean(hope) if ga==1  // 和HOPE没区别
bysort year: egen djt=sum(djtga)   // 1993年之后为1，之前为0
bysort state: egen meandjt=mean(djt)
g dtil=djt-meandjt   //求出d波浪号

/* Obtain difference in differences coefficient*/
reg eta dtil if ga==1,noc
matrix alpha=e(b)  
	
/* Simulations*/
quietly {
  foreach st of numlist 11/16 21/23 31/33 35 41/47 51/56 58 62 63 73 74 81/84 86 87 91/95 {
    capture {
      reg eta dtil if state==`st'&ga!=1, noc
      matrix alpha=alpha\e(b)
    }
  }
} 
matrix asim=alpha[2...,1]  //去掉第一个reg eta dtil if ga==1,noc 系数后的dtil系数矩阵
matrix alpha=alpha[1,1] // reg eta dtil if ga==1,noc 的dtil系数

第四步，模拟出 $\hat{α}$ 的分布；

/* Confidence intervals */
svmat alpha 
svmat asim

sum alpha
gen alpha=r(mean) 
g ci=alpha-asim

/* form confidence intervals */
local numst=42
local i025=floor(0.025*(`numst'-1)) // 95%置信区间
local i975=ceil(0.975*(`numst'-1))

local i05=floor(0.050*(`numst'-1))  //90%置信区间
local i95=ceil(0.950*(`numst'-1))

第五步，根据要求选择 $\hat{α}$ 的置信区间；

sort asim
sum ci if _n==`i025'|_n==`i975'
display as text "95% Confidence interval=" as result _newline(2) r(min) _col(15) r(max)

由此便得到 Conley-Taber 在 5% 水平下的置信区间：

. sum ci if _n==`i025'|_n==`i975'

 Variable |  Obs        Mean    Std. Dev.       Min        Max
----------+---------------------------------------------------
       ci |    2    .0981308    .1535922  -.0104753   .2067369

. display as text "95% Confidence interval=" as result _newline(2) r(min) _col(15) r(max)
95% Confidence interval=

-.01047528    .20673692

4. 参考文献

Moulton B R. An illustration of a pitfall in estimating the effects of aggregate variables on micro units[J]. The review of Economics and Statistics, 1990: 334-338. -PDF-
Donald S G, Lang K. Inference with difference-in-differences and other panel data[J]. The review of Economics and Statistics, 2007, 89(2): 221-233. -PDF-
Cascio E U, Schanzenbach D W. The impacts of expanding access to high-quality preschool education[R]. National Bureau of Economic Research, 2013. -PDF-
Nunn N, Wantchekon L. The slave trade and the origins of mistrust in Africa[J]. American Economic Review, 2011, 101(7): 3221-52. -PDF-
Pinotti P. The economic costs of organised crime: Evidence from Southern Italy[J]. The Economic Journal, 2015, 125(586): F203-F232. -PDF-
Dube A, Lester T W, Reich M. Minimum wage shocks, employment flows, and labor market frictions[J]. Journal of Labor Economics, 2016, 34(3): 663-704. -PDF-
Rockoff J E. Does mentoring reduce turnover and improve skills of new employees? Evidence from teachers in New York City[R]. National Bureau of Economic Research, 2008. -PDF-
Wing C, Simon K, Bello-Gomez R A. Designing difference in difference studies: best practices for public health policy research[J]. Annual review of public health, 2018, 39. -PDF-
Decarolis, F. "Awarding price, contract performance, and bids screening: Evidence from procurement auctions." American Economic Journal: Applied Economics 6.1 (2014): 108-32. -PDF-

5. 相关推文

Note： 产生如下推文列表的命令为：
lianxh did, m
安装最新版 lianxh 命令：
ssc install lianxh, replace

专题	嘉宾	直播/回看视频
⭐ 最新专题		因果推断, 空间计量，寒暑假班等
⭕ 数据清洗系列	游万海	直播, 88 元，已上线
研究设计	连玉君	我的特斯拉-实证研究设计，-幻灯片-
面板模型	连玉君	动态面板模型，-幻灯片-
面板模型	连玉君	直击面板数据模型 [免费公开课，2小时]

DID：仅有几个实验组样本的倍分法 (双重差分)

1. 简介

2. 理论推导

3. Stata 范例

4. 参考文献

5. 相关推文

相关课程

课程一览

关于我们

热门资讯